import org.gradle.util.VersionNumber

plugins {
    id 'com.android.library'
    id 'org.jetbrains.kotlin.android'
}

android {
    compileSdk 34
    namespace "com.tencent.qcloud.tuikit.tuicallkit"

    defaultConfig {
        versionName "3.0"
        versionCode 1
        minSdkVersion 19
        targetSdkVersion 34
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }

    def callSourceJavaVersion = JavaVersion.VERSION_1_8
    VersionNumber currentGradleVersion = VersionNumber.parse(gradle.gradleVersion)
    if (currentGradleVersion.major >= 8) {
        callSourceJavaVersion = JavaVersion.VERSION_17
    }

    compileOptions {
        sourceCompatibility callSourceJavaVersion
        targetCompatibility callSourceJavaVersion
    }
}

dependencies {
    api fileTree(include: ['*.jar', '*.aar'], dir: 'libs')

    api 'androidx.appcompat:appcompat:1.3.1'
    api 'com.google.android.material:material:1.4.0'
    api 'androidx.recyclerview:recyclerview:1.2.1'
    api 'androidx.constraintlayout:constraintlayout:1.1.3'
    api "com.google.code.gson:gson:2.9.1"

    def projects = this.rootProject.getAllprojects().stream().map { project -> project.name }.collect()
//    if (projects.contains("tuicore")) {
        api project(':tuicore')
//    } else {
//        api "com.tencent.imsdk:imsdk-plus:8.6.7019"
//        api "com.tencent.liteav.tuikit:tuicore:8.6.7020"
//    }
    if (projects.contains("engine_source")) {
        api project(':engine_source')
    } else {
        api rootProject.getProperties().containsKey("liteavSdk") ? rootProject.ext.liteavSdk : "com.tencent.liteav:LiteAVSDK_Professional:12.4+"
        api rootProject.getProperties().containsKey("roomEngineSdk") ? rootProject.ext.roomEngineSdk : "io.trtc.uikit:rtc_room_engine:3.1.+"
    }
    if (projects.contains("common")) {
        api project(':common')
    } else {
        api 'io.trtc.uikit:common:3.1.0.946'
    }
}